ADO Mempercepat Dengan GetString()
Gunakan metode GetString() untuk mempercepat skrip ASP Anda (daripada menggunakan beberapa Response.Write).
Beberapa Respon.Tulis
Contoh berikut menunjukkan salah satu cara untuk menampilkan kueri database dalam tabel HTML:
<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
<tr>
<td><%Response.Write(rs.fields("Companyname"))%></td>
<td><%Response.Write(rs.fields("Contactname"))%></td>
</tr>
<%rs.MoveNext
loop%>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>
Untuk kueri yang besar, ini dapat memperlambat waktu pemrosesan skrip, karena banyak perintah Response.Write harus diproses oleh server.
Solusinya adalah membuat seluruh string, dari <table> hingga </table>, lalu mengeluarkannya - menggunakan Response.Write sekali saja.
Metode GetString()
Metode GetString() memungkinkan Anda untuk menampilkan string hanya dengan satu Response.Write. Ini juga menghilangkan kode do...loop dan uji kondisional yang memeriksa apakah recordset berada di EOF.
Sintaksis
str = rs.GetString(format,rows,coldel,rowdel,nullexpr)
Untuk membuat tabel HTML dengan data dari recordset, kita hanya perlu menggunakan tiga parameter di atas (semua parameter bersifat opsional):
- coldel - HTML yang digunakan sebagai pemisah kolom
- rowdel - HTML yang digunakan sebagai pemisah baris
- nullexpr - HTML yang digunakan jika kolom NULL
Catatan: Metode GetString() adalah fitur ADO 2.0. Anda dapat mengunduh ADO 2.0 di https://www.microsoft.com/data/download.htm .
Dalam contoh berikut, kita akan menggunakan metode GetString() untuk menyimpan recordset sebagai string:
Contoh
<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
str=rs.GetString(,,"</td><td>","</td></tr><tr><td>"," ")
%>
<table border="1" width="100%">
<tr>
<td><%Response.Write(str)%></td>
</tr>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>
Variabel str di atas berisi string dari semua kolom dan baris yang dikembalikan oleh pernyataan SQL SELECT. Di antara setiap kolom akan muncul HTML </td><td>, dan di antara setiap baris, HTML </td></tr><tr><td> akan muncul. Ini akan menghasilkan HTML yang tepat yang kita butuhkan hanya dengan satu Response.Write.